【SAS 함수】 184. FSEP

o FSEP

 

---

FGET 함수를 위한 구분자를 설정한다.

Category:

외부 파일 접근 및 처리 함수 (External Files)

 

---

문 법

FSEP (file-id,character(s))

Arguments

     file-id       는 FOPEN함수에 의해 반환된 인식자 지정

 

---

관련 함수

함수명	함수내용
DCLOSE	DOPEN 함수에 의해 열었던 디렉토리를 닫는다.
DOPEN	디렉토리 OPEN하여서 0보다 큰 directory identifier value을 반환한다.
FCLOSE	외부파일, 디렉토리, 디렉토리 멤버를 닫는다.
FETCH	SAS 데이터 세트로부터 현재 관측치 다음의 관측치를 데이터 세트 데이터 벡터(DDV) 안으로 관측치를 읽는다.
FETCHOBS	SAS 데이터 세트로부터 지정한 관측치를 데이터 SET 데이터 벡터(DDV)로 읽는다.
FGET	파일 데이터 벡터(FDB)로부터 변수에 데이터를 복사한다.
FILENAME	SAS 파일 참조자(fileref)를 외부 파일 또는 출력 장치와 연결한다. 이와 반대로 파일 참조자(Fileref)와 외부 파일의 관계를 해제할 수 있으며, 외부 파일 속성을 출력할 수 있다.
FOPEN	외부파일을 연다.
FPOS	파일 데이터 버퍼(FDB)에서 칼럼 포인터의 위치를 설정한다.
FREAD	외부파일에서 FDB로 레코드를 읽는다.
FREWIND	파일의 시작에 파일 포인터를 배치하고 값을 반환한다.
FSEP	FGET함수를 위한 구분자를 설정한다.
MOPEN	디렉토리 아이디와 멤버 이름에 의해 파일을 연다.
NOTE	SAS 데이터 세트의 현재 관측치에 대한 관측치 아이디를 반환한다.
OPEN	SAS 데이터 세트를 OPEN하고, 데이터 세트 ID를 반환한다.
POINT	NOTE함수에 의해 확인된 위치에 관측치를 이동시키고, 값을 반환한다.
SYSMSG	마지막 데이터 세트나 외부 파일 함수 실행으로부터 에러메시지나 경고 메시지 반환한다.

 

---

예 제

 

예 제 1 :

FGET함수에서 사용하기 위한 구분자(‘,’)를 설정한다.

SAS Statements

FILENAME FSEP "c:\FSEP.txt";

data _null_;
     file FSEP;
     put "John J. Doe,Male,25,Weight Lifter";
     put "Pat O’Neal,Female,22,Gymnast";
run;

data FSEP1;
     rc     = filename('thefile','c:\FSEP.txt');
     fileid = fopen('thefile');
     rc     = fsep(fileid,',');
     sysrc  = fread(fileid);
     length cval $18.;
     cval   = ' ';
     rc = fget(fileid,cval);
     
     do while (rc ne -1);
        put cval = ;
        rc = fget (fileid,cval);
     end;
     
     rc=fclose(fileid);
run;

 

Results

cval=John J. Doe
cval=Male
cval=25
cval=Weight Lifter

 

---

예 제 2 :

FGET함수에서 사용하기 위한 구분자(‘,’)를 설정한다.

SAS Statements

data FSEP2;
     rc  = filename('thefile','c:\FSEP.txt');
     fid = fopen('thefile');
     rc  = fsep(fid,',');
     length name gender age work $15.;
     
     do while(fread(fid) = 0);
        rc = fget(fid,name);
        rc = fget(fid,gender);
        rc = fget(fid,age);
        rc = fget(fid,work);
        put name= gender= age= work=;
     end;
     
     rc=fclose(fid);
run;

 

Results

name=John J. Doe gender=Male age=25 work=Weight Lifter
name=Pat O’Neal gender=Female age=22 work=Gymnast

 

---

엑셀(EXCEL)과 SAS 함수(SAS Function) 비교 리스트 링크

 

SAS 함수(SAS Function) 리스트 링크