【SAS Statement】 FILENAME 구문, CLIPBOARD 접근 방법

o FILENAME 구문, CLIPBOARD 접근 방법

 

---

1. 목 적 

FILENAME 구문, CLIPBOARD 접근 방법은 HOST 컴퓨터의 클립보드에서 데이터를 읽고, 반대로 클립보드에 데이터를 작성한다. 동일하게 마우스를 사용하여서 탐색기의 Pop-up 메뉴에서 “클립보드에 복사”(Copy contents to Clipboard)를 사용하여 데이터를 클립보드에 복사할 수 있다.(Ctrl+C / Ctrl+V)

 

---

2. 문 법 

FILENAME fileref CLIPBRD paste-buffer-name>;

 

Fileref

유효한 파일 참조자의 이름을 지정한다.

 

CLIPBRD

클립보드에서 데이터를 읽고 작성할 수 있는 접근 방법을 지정한다.

 

BUFFER=paste-buffer-name

붙이기 버퍼를 생성하고, 이름을 지정한다. STORE 명령문에서 BUFFER=인수를 사용하여 붙이기 버퍼 이름을 지정함으로써 다수의 붙이기 버퍼를 생성 할 수 있다.

 

---

3. 범 주

SAS 기본 구문 (데이터 접근)

 

4. 상세설명

FILENAME 구문의 CLIPBOARD 접근 방법으로 SAS 내의 데이터 공유 및 SAS와 SAS이외의 다른 어플리케이션 사이의 데이터 공유가 가능하다.

 

---

5. 비교 사항

• STORE 명령어는 현재 윈도우에서 범위가 지정된 텍스트를 복사하여서 붙이기 버퍼에 복사된 내용을 저장한다.
• 동일하게 탐색기 화면에서 pop-up 메뉴 항목의 “클립보드에 복사”(Copy contents to Clipboard)를 사용하여 데이터를 클립보드에 복사 할 수 있다.

 

---

6. 비교 구문

구문명	구문 내용
FILENAME 구문	SAS 파일 참조자(fileref)를 외부 파일 또는 출력 장치와 연결한다. 이와 반대로 파일 참조자(Fileref)와 외부 파일의 관계를 해제할 수 있으며, 외부 파일 속성을 출력할 수 있다.
FILENAME 구문, CATALOG 접근 방법	SAS 파일참조자(fileref)가 SAS 카탈로그를 참조하도록 지정한다. 외부 파일에 접근하는 방식과 유사하게 SAS 명령어, SAS 문장, 프로시져를 사용하여 SAS 카탈로그에 접근할 수 있다. 이 접근 방법은 SAS 카탈로그에 존재하는 자동 호출 매크로를 직접 호출할 수 있다.
FILENAME 구문, CLIPBOARD 접근 방법	HOST 컴퓨터의 클립보드에서 데이터를 읽고, 반대로 클립보드에 데이터를 작성한다. 동일하게 마우스를 사용하여서 탐색기의 Pop-up 메뉴에서 “클립보드에 복사”(Copy contents to Clipboard)를 사용하여 데이터를 클립보드에 복사할 수 있다.(Ctrl+C / Ctrl+V)
FILENAME 구문, EMAIL(SMTP) 접근 방법	간이 전자 이메일 전송 프로토콜(Simple Mail Transfer Protocol, SMTP) 인터페이스를 사용하여 SAS 프로그래밍 구문에서 전자 메일을 전송한다.
FILENAME 구문, FTP 접근 방법	FTP 프로토콜(protocol)을 사용하여 원격(remote) 파일에 접근하여서 파일 다운로드와 업로드 작업을 수행할 수 있다.
FILENAME 구문, SOCKET 접근 방법
FILENAME 구문, SFTP 접근 방법	SFTP 프로토콜을 사용하여 원격(remote) 파일에 접근하여서 파일 다운로드와 업로드 작업을 수행할 수 있다.
FILENAME 구문, URL 접근 방법	URL 접근 방법을 사용하여 원격(remote) 파일에 접근하여 작업을 수행할 수 있다.
STORE 명령어

 

---

7. 예 제

 

예제1 : 클립보드에 HTML형식으로 데이터 세트를 작성하기 위하여 ODS 사용하기.

다음 예제는 입력 파일로 SASHELP.AIR 데이터 세트를 사용한다. ODS는 클립보드에 HTML 형식으로 데이터 세트를 작성하기 위하여 사용된다.

 

SAS Statements

filename _temp_ clipbrd;
   ods noresults;
   ods listing close;
   ods html file=_temp_ rs=none style=minimal;
   proc print data=Sashelp.'Air'N noobs;
run;
ods html close;
ods results;
ods listing;
filename _temp_;

 

---

예제2 : 데이터 스텝을 사용하여 클립보드에 콤마 구분자를 사용하여 데이터 세트를 작성하기

다음 예제는 입력 파일로 SASHELP.AIR 데이터 세트를 사용한다. 데이터는 클립보드에 콤마로 분리하여 저장하도록 데이터 스텝을 작성한다.

 

SAS Statements

filename _temp1_ temp;
filename _temp2_ clipbrd;
proc contents data=Sashelp."Air"N out=info noprint;
proc sort data=info;
   by npos;
run;
 
data _null_;
   set info end=eof;
   file _temp1_ dsd;
   put name @@;
   if _n_=1 then do;
      call execute("data _null_; set Sashelp.""Air""N; file _temp1_ dsd mod; put");
   end;
   call execute(trim(name));
   if eof then call execute('; run;');
run;
 
data _null_;
   infile _temp1_;
   file _temp2_;
   input;
   put _infile_;
run;
 
filename _temp1_ clear;
filename _temp2_ clear;

 

---

예제3 : 클립보드에 텍스트를 작성하기 위하여 데이터 스텝 사용하기

다음 예제는 클립보드에 3개의 라인을 작성한다.

 

SAS Statements

filename clippy clipbrd;
 
data _null_;
   file clippy;
   put 'Line 1';
   put 'Line 2';
   put 'Line 3';
run;

 

---

예제4 : 데이터 스텝을 사용하여 클립보드에서 텍스트를 검색하기

다음 예제는 클립보드에 3개의 라인을 작성하고, 그것을 로그에 출력한다.

 

SAS Statements

filename clippy clipbrd;
 
data _null_;
   file clippy;
   put 'Line 1';
   put 'Line 2';
   put 'Line 3';
run;
 
data _null_;
   infile clippy;
   input;
   put _infile_;
run;

 

---

 

---

[SAS Statement] SAS 데이터 스텝 구문 사전 목록]

 

SAS 함수(SAS Function) 리스트 링크